**EDV-Schulen des Landkreises Deggendorf**

**1. Probe Kurzarbeit in ABAP – Lösung**

**Aufgabe 1 – ZXXX\_CL\_WPAPIER**

class ZXXX\_CL\_WPAPIER definition  
  public  
  final  
  create public .  
  
public section.  
  
  types:  
    TT\_KURSE TYPE TABLE OF zpe\_kurse .  
  
  methods CONSTRUCTOR  
    importing  
      value(IN\_WKN) type ZPE\_WPAPIER-WKN .  
  class-methods GET\_COUNTWPAPIER  
    returning  
      value(RN\_ANZAHL\_WPAPIER) type INT4 .  
  methods DISPLAY\_ATTRIBUTES .  
  methods GET\_KURSE  
    exporting  
      !ET\_KURSE type TT\_KURSE .  
  methods GET\_LASTKURS  
    exporting  
      !ES\_KURSE type ZPE\_KURSE .  
  PROTECTED SECTION.  
private section.  
  
  data MS\_WPAPIER type ZPE\_WPAPIER .  
  
  methods GET\_COUNTKURSE  
    returning  
      value(RN\_ANZAHL\_KURSE) type INT4 .  
ENDCLASS.  
  
  
  
CLASS ZXXX\_CL\_WPAPIER IMPLEMENTATION.  
  
  
*\* <SIGNATURE>---------------------------------------------------------------------------------------+*  
*\* | Instance Public Method ZXXX\_CL\_WPAPIER->CONSTRUCTOR*  
*\* +-------------------------------------------------------------------------------------------------+*  
*\* | [--->] IN\_WKN                         TYPE        ZPE\_WPAPIER-WKN*  
*\* +--------------------------------------------------------------------------------------</SIGNATURE>*  
  METHOD constructor.  
    SELECT SINGLE \*  
      FROM zpe\_wpapier  
      WHERE wkn = @in\_wkn  
      INTO @ms\_wpapier.  
  
    IF sy-subrc <> 0.  
      SELECT SINGLE \*  
        FROM zpe\_wpapier  
        WHERE wkn = 1  
        INTO @ms\_wpapier.  
    ENDIF.  
  ENDMETHOD.

*\* <SIGNATURE>---------------------------------------------------------------------------------------+*  
*\* | Instance Public Method ZXXX\_CL\_WPAPIER->DISPLAY\_ATTRIBUTES*  
*\* +-------------------------------------------------------------------------------------------------+*  
*\* +--------------------------------------------------------------------------------------</SIGNATURE>*  
  METHOD display\_attributes.  
    WRITE: / |WKN: { ms\_wpapier-wkn }, Titel: { ms\_wpapier-titel }, Emittent: { ms\_wpapier-emittent }|,  
           / |Anzahl Kurse: { me->get\_countkurse( ) }|.  
  ENDMETHOD.  
  
  
*\* <SIGNATURE>---------------------------------------------------------------------------------------+*  
*\* | Instance Private Method ZXXX\_CL\_WPAPIER->GET\_COUNTKURSE*  
*\* +-------------------------------------------------------------------------------------------------+*  
*\* | [<-()] RN\_ANZAHL\_KURSE                TYPE        INT4*  
*\* +--------------------------------------------------------------------------------------</SIGNATURE>*  
  METHOD get\_countkurse.  
    SELECT COUNT( \* )  
      FROM zpe\_kurse  
      WHERE wkn = @ms\_wpapier-wkn  
      INTO @rn\_anzahl\_kurse.  
  ENDMETHOD.  
  
  
*\* <SIGNATURE>---------------------------------------------------------------------------------------+*  
*\* | Static Public Method ZXXX\_CL\_WPAPIER=>GET\_COUNTWPAPIER*  
*\* +-------------------------------------------------------------------------------------------------+*  
*\* | [<-()] RN\_ANZAHL\_WPAPIER              TYPE        INT4*  
*\* +--------------------------------------------------------------------------------------</SIGNATURE>*  
  METHOD get\_countwpapier.  
    SELECT COUNT(\*)  
      FROM zpe\_wpapier  
      INTO @rn\_anzahl\_wpapier.  
  ENDMETHOD.  
  
  
*\* <SIGNATURE>---------------------------------------------------------------------------------------+*  
*\* | Instance Public Method ZXXX\_CL\_WPAPIER->GET\_KURSE*  
*\* +-------------------------------------------------------------------------------------------------+*  
*\* | [<---] ET\_KURSE                       TYPE        TT\_KURSE*  
*\* +--------------------------------------------------------------------------------------</SIGNATURE>*  
  METHOD get\_kurse.  
    SELECT \*  
      FROM zpe\_kurse  
      WHERE wkn = @ms\_wpapier-wkn  
      INTO TABLE @et\_kurse.  
  ENDMETHOD.

*\* <SIGNATURE>---------------------------------------------------------------------------------------+*  
*\* | Instance Public Method ZXXX\_CL\_WPAPIER->GET\_LASTKURS*  
*\* +-------------------------------------------------------------------------------------------------+*  
*\* | [<---] ES\_KURSE                       TYPE        ZPE\_KURSE*  
*\* +--------------------------------------------------------------------------------------</SIGNATURE>*  
  METHOD get\_lastkurs.  
    SELECT MAX( datum )  
      FROM zpe\_kurse  
      WHERE wkn = @ms\_wpapier-wkn  
      INTO @DATA(lv\_max\_datum).  
  
    SELECT SINGLE \*  
      FROM zpe\_kurse  
      WHERE wkn = @ms\_wpapier-wkn AND datum = @lv\_max\_datum  
      INTO @es\_kurse.  
  
*\*    SELECT SINGLE wkn, datum, kurswert*  
*\*      FROM zpe\_kurse*  
*\*      WHERE wkn = @ms\_wpapier-wkn*  
*\*      AND datum = ( SELECT MAX( datum ) FROM zpe\_kurse WHERE wkn = @ms\_wpapier-wkn )*  
*\*      INTO CORRESPONDING FIELDS OF @es\_kurse.*  
  ENDMETHOD.  
ENDCLASS.

**Aufgabe 1 – ZXXX\_PERL\_2022\_SA1\_A2**

(Quellcode in grau war vorgegeben)

DATA: gn\_wkn      TYPE zpe\_wpapier-wkn VALUE 878841,  
      gt\_kurse    TYPE zXXX\_cl\_wpapier=>tt\_kurse,  
      go\_wpapier  TYPE REF TO zXXX\_cl\_wpapier,  
      gs\_lastkurs TYPE zpe\_kurse.  
  
go\_wpapier = NEW #( in\_wkn = gn\_wkn ).  
  
go\_wpapier->get\_kurse(  
  IMPORTING  
    et\_kurse = gt\_kurse *" Kurse*  
).  
  
go\_wpapier->get\_lastkurs(  
  IMPORTING  
    es\_kurse = gs\_lastkurs  
).  
  
WRITE: / |Anzahl aller Wertpapiere: { zXXX\_cl\_wpapier=>get\_countwpapier( ) }|.  
SKIP.  
  
go\_wpapier->display\_attributes( ).  
  
ULINE.  
WRITE: 'Datum', 16 'Kurswert'.  
LOOP AT gt\_kurse ASSIGNING FIELD-SYMBOL(<fs\_kurs>).  
  WRITE: / <fs\_kurs>-datum, <fs\_kurs>-kurswert.  
ENDLOOP.  
ULINE.  
WRITE: / |Letzter Kurswert am { gs\_lastkurs-datum DATE = USER }: { gs\_lastkurs-kurswert }|.

**Aufgabe 2 –** **Übersicht Kundendepots**

PARAMETERS: p\_knr TYPE zpe\_kunde-kundennr DEFAULT 624456.  
  
DATA: gt\_depots TYPE zpe\_tt\_depot.  
  
SELECT SINGLE \*  
  FROM zpe\_kunde  
  WHERE kundennr = @p\_knr  
  INTO @DATA(gs\_kunde).  
  
SELECT depotnr, depottyp  
  FROM zpe\_depot  
  WHERE kundennr = @p\_knr  
  ORDER BY depotnr  
  INTO CORRESPONDING FIELDS OF TABLE @gt\_depots.  
  
LOOP AT gt\_depots ASSIGNING FIELD-SYMBOL(<fs\_depot>).  
  SELECT SUM( Anzahl )  
    FROM zpe\_depot\_pos  
    WHERE depotnr = @<fs\_depot>-depotnr  
    INTO @<fs\_depot>-anzahl.  
ENDLOOP.  
  
WRITE: / |{ gs\_kunde-vorname } { gs\_kunde-nachname }(Kundennr { p\_knr })|.  
ULINE.  
WRITE: / 'Depotnr', 15 'Depottyp', 30 'Anzahl'.  
LOOP AT gt\_depots ASSIGNING <fs\_depot>.  
  WRITE: / <fs\_depot>-depotnr, 15 <fs\_depot>-depottyp, 26 <fs\_depot>-anzahl.  
ENDLOOP.